terraform {
  required_version = ">= 1.7.0"
  required_providers {
    hcloud = {
      source  = "hetznercloud/hcloud"
      version = "~> 1.49"
    }
    template = {
      source  = "hashicorp/template"
      version = "~> 2.2"
    }
  }
}

provider "hcloud" {
  token = var.hcloud_token
}

locals {
  servers    = yamldecode(file("${path.module}/../../inventory/servers.yaml")).servers
  cloud_init = file("${path.module}/cloud_init.yaml")
}

resource "hcloud_ssh_key" "admin" {
  name       = "railliance-admin"
  public_key = file("${path.module}/../../keys/admin_ssh.pub")
}

resource "hcloud_server" "srv" {
  for_each    = { for s in local.servers : s.name => s }
  name        = each.value.name
  image       = coalesce(each.value.image, "ubuntu-24.04")
  server_type = each.value.type
  location    = each.value.region
  ssh_keys    = [hcloud_ssh_key.admin.id]
  user_data   = local.cloud_init

  labels = {
    role   = each.value.role
    labels = join(",", try(each.value.labels, []))
    env    = "default"
  }
}

output "servers" {
  value = { for k, v in hcloud_server.srv : k => v.ipv4_address }
}